build.gradle

/*
 * MIT License
 *
 * Copyright (c) 2020 NUM Technology Ltd
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated
 * documentation files (the "Software"), to deal in the Software without restriction, including without limitation
 * the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and
 * to permit persons to whom the Software is furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in all copies or substantial portions of
 * the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE
 * WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS
 * OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR
 * OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
 *
 */
//file:noinspection SpellCheckingInspection

buildscript {

    ext {
        lombokVersion = '1.18.22'
    }

}

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'signing'
    id 'idea'
    id "org.sonarqube" version "3.0"
}

repositories {
    mavenLocal()
    mavenCentral()
}

javadoc {
    options.encoding = 'UTF-8'
    failOnError=false
}

apply plugin: 'java'
apply plugin: 'java-library'
apply plugin: 'antlr'
apply plugin: 'maven-publish'
apply plugin: 'application'
apply plugin: 'application'
apply plugin: 'jacoco'

mainClassName = "uk.modl.server.ModlServer"

sourceCompatibility = 1.8
targetCompatibility = 1.8
compileJava.options.encoding = "UTF-8"
compileTestJava.options.encoding = "UTF-8"

group = "uk.modl"
applicationName = "java-interpreter"
archivesBaseName = "java-interpreter"
version = "1.0.0"
mainClassName = "uk.modl.interpreter.Interpret"

def isSnapshot = version.endsWith("SNAPSHOT")

dependencies {

    testCompile group: 'junit', name: 'junit', version: '4.12'

    // https://mvnrepository.com/artifact/com.fasterxml.jackson.core/jackson-core
    compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.12.3'

    // Dependency and config for Lombok annotations
    compile("org.projectlombok:lombok:${lombokVersion}")
    annotationProcessor("org.projectlombok:lombok:${lombokVersion}")
    testAnnotationProcessor("org.projectlombok:lombok:${lombokVersion}")

    compile group: 'org.slf4j', name: 'log4j-over-slf4j', version: '1.7.29'
    compile group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.17.1'

    // https://mvnrepository.com/artifact/io.vavr/vavr
    compile 'io.vavr:vavr:0.10.4'

}


task sourceJar(type: Jar) {
    from sourceSets.main.allJava
    classifier 'sources'
}


task javadocJar(type: Jar, dependsOn: javadoc) {
    from javadoc
    classifier 'javadoc'
}


artifacts {
    archives jar
    archives sourceJar
    archives javadocJar
}

/***********
 * MAVEN PUBLISHING
 ***********/

def fatJarFile = file("$buildDir/libs/interpreter-" + version + ".jar")
def fatJarArtifact = artifacts.add('archives', fatJarFile) {
    builtBy('customFatJar')
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            customisePom(pom)

            groupId = "uk.modl"
            artifactId = 'java-interpreter'

            from components.java

            artifact(sourceJar) {
                classifier = 'sources'
            }

            artifact(javadocJar) {
                classifier = 'javadoc'
            }

            artifact(fatJarArtifact) {
                classifier = 'exe'
            }
        }
    }
    repositories {
        maven {
            def releasesRepoUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            def snapshotsRepoUrl = "$buildDir/repos/snapshots"
            url = isSnapshot ? snapshotsRepoUrl : releasesRepoUrl
            if (!isSnapshot) {
                def stUser
                def stPwd

                if (project.hasProperty('sonatypeUsername')) {
                    stUser = sonatypeUsername
                } else {
                    stUser = "notdefined"
                    logger.warn("sonatypeUsername not defined. Please update your gradle config file")
                }

                if (project.hasProperty('sonatypePassword')) {
                    stPwd = sonatypePassword
                } else {
                    stPwd = "notdefined"
                    logger.warn("sonatypePassword not defined. Please update your gradle config file")
                }

                credentials {
                    username stUser
                    password stPwd
                }
            }
        }
    }
}


signing {
    required {
        // signing is required if this is a release version and the artifacts are to be published
        !isSnapshot && tasks.withType(PublishToMavenRepository).find {
            gradle.taskGraph.hasTask it
        }
    }
    sign publishing.publications
}


def customisePom(pom) {
    pom.withXml {
        def root = asNode()

        // eliminate test-scoped dependencies (no need in maven central POMs)
        root.dependencies.removeAll { dep ->
            dep.scope == "test"
        }

        // add all items necessary for maven central publication
        root.children().last() + {
            resolveStrategy = Closure.DELEGATE_FIRST

            name 'java-interpreter'
            description 'Java interpreter for MODL language'
            url 'https://github.com/MODLanguage/java-interpreter'

            licenses {
                license {
                    name 'MIT license'
                    url 'https://opensource.org/licenses/MIT'
                    distribution 'repo'
                }
            }

            scm {
                connection 'scm:git:git://MODLanguage/java-interpreter.git'
                developerConnection 'scm:git:git://MODLanguage/java-interpreter.git'
                url 'https://github.com/MODLanguage/java-interpreter'
            }
            developers {
                developer {
                    id 'tony.walmsley@num.uk'
                    name 'Tony Walmsley'
                    email 'tony.walmsley@num.uk'
                }
            }
        }
    }
}

task customFatJar(type: Jar) {
    manifest {
        attributes 'Main-Class': 'Interpret'
    }
    baseName = 'interpreter'
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    with jar
}

// ====== JACOCO TEST COVERAGE ======
jacocoTestReport {
    reports {
        xml.enabled true
    }
}
test.finalizedBy jacocoTestReport