bevy_cli/flake.nix at main · TheBevyFlock/bevy_cli · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
{
  description = "A Bevy CLI tool and linter";

  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      flake-utils,
      nixpkgs,
      rust-overlay,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system}.extend rust-overlay.overlays.default;

        nativeBuildInputs = with pkgs; [ pkg-config ];

        buildInputs = with pkgs; [ openssl ];

        toolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;

        rustPlatform = pkgs.makeRustPlatform {
          cargo = toolchain;
          rustc = toolchain;
        };
      in
      {
        packages = {
          default = self.outputs.packages.${system}.bevy;
          bevy = rustPlatform.buildRustPackage {
            pname = "bevy";
            version = "0.1.0-dev";
            src = ./.;
            cargoLock.lockFile = ./Cargo.lock;
            doCheck = false;
            cargoBuildFlags = [ "--all" ];

            nativeBuildInputs = nativeBuildInputs ++ (with pkgs; [ makeBinaryWrapper ]);
            postInstall = ''
              for bin in $out/bin/bevy{,_lint}; do
                wrapProgram $bin --set BEVY_LINT_SYSROOT ${toolchain}
              done
            '';

            inherit buildInputs;
          };
        };

        devShells.default = pkgs.mkShell { inherit buildInputs nativeBuildInputs; };
      }
    );
}