versionparser/examples/build.gradle.kts at master · cthing/versionparser · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
plugins {
    `java-library`
    checkstyle
    alias(libs.plugins.dependencyAnalysis)
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(libs.versions.java.get())
    }
}

dependencies {
    api(project(":"))

    implementation(libs.assertJ)
}

checkstyle {
    toolVersion = libs.versions.checkstyle.get()
    isIgnoreFailures = false
    configFile = file("../dev/checkstyle/checkstyle.xml")
    configDirectory = file("../dev/checkstyle")
    isShowViolations = true
}

tasks {
    withType<JavaCompile> {
        options.release = libs.versions.java.get().toInt()
        options.compilerArgs.addAll(listOf("-Xlint:all", "-Xlint:-options", "-Werror"))
    }
}

listOf("CalVerExample",
       "DebianExample",
       "GradleExample",
       "JavaVersionExample",
       "MavenExample",
       "NpmExample",
       "RubyGemsExample").forEach { example ->
    tasks.register("run$example", JavaExec::class) {
        group = "Example"
        description = "Run $example program"
        mainClass = "org.cthing.versionparser.examples.$example"
        classpath = sourceSets["main"].runtimeClasspath
    }
}