ExpenseExamples.hs

{-# LANGUAGE DataKinds #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE QuasiQuotes #-}

module ExpenseExamples
    (
      getTwoPagesOfExpenses
    ) where

import Splitwise
import Splitwise.Data.Cursors

import Control.Monad.Loops (unfoldrM)
import Data.Aeson.Schema
import Data.Default
import Data.String (fromString)
import System.Environment

-- | Fetch at most 2 pages of 2 expenses each (up to 4 expenses total)
-- using the sample 'ExpensesPaginateTwoCursor' pagination strategy.
getTwoPagesOfExpenses :: IO ()
getTwoPagesOfExpenses = do
  apiAuth <- SplitwiseAPIKeyAuth . fromString <$> getEnv "SPLITWISE_API_TOKEN"
  result <- runSplitwise apiAuth $ do
    let cursor = mkTwoPagesOfTwoExpensesCursor def
    unfoldrM (unfoldWith twoPagesOfTwoExpensesCursorNextState getExpensesWithCursor) (GoCursor cursor)
  case result of
    Left err -> putStrLn $ "Error: " <> show err
    Right pages -> mapM_ printPage (zip [1..] pages)
  where
    printPage :: (Int, [Object ExpenseSchema]) -> IO ()
    printPage (n, expenses) = do
      putStrLn $ "Page " <> show n <> ":"
      mapM_ printExpense expenses

    printExpense :: Object ExpenseSchema -> IO ()
    printExpense e = putStrLn $
      "  " <> show ([get| .id |] e) <> ": " <> show ([get| .description |] e) <> " (" <> show ([get| .cost |] e) <> ")"