Pas2JS-WebGL/GLTypes.pas at master · genericptr/Pas2JS-WebGL · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
unit GLTypes;
interface
uses
	WebGL, JS, Math, SysUtils;

type
	TScalar = single;

type
	TVec2 = record
		x, y: TScalar;
	end;

type
	TVec3 = record
		x, y, z: TScalar;
	end;

type
	TRGBAb = array of GLubyte;
	TRGBAf = array of TScalar;

{ Vec3 }
function V3(x, y, z: TScalar): TVec3;
function ToFloats(v: TVec3): TJSFloat32List; overload;
function VecStr(v: TVec3): string; overload;
procedure Show (v: TVec3);

// math functions since we don't have advanced records
function Add (v: TVec3; amount: TScalar): TVec3; overload;
function Add (v: TVec3; amount: TVec3): TVec3; overload;
function Subtract (v: TVec3; amount: TScalar): TVec3; overload;
function Subtract (v: TVec3; amount: TVec3): TVec3; overload;
function Multiply (v: TVec3; amount: TScalar): TVec3; overload;
function Multiply (v: TVec3; amount: TVec3): TVec3; overload;
function Divide (v: TVec3; amount: TScalar): TVec3; overload;
function Divide (v: TVec3; amount: TVec3): TVec3; overload;
function Sum (v: TVec3): TScalar; overload;
function Magnitude(v: TVec3): TScalar; overload;
function SquaredLength (v: TVec3): TScalar; overload;
function Normalize (v: TVec3): TVec3; overload;
function Dot (v: TVec3; point: TVec3): TScalar; overload;
function Cross (v: TVec3; point: TVec3): TVec3; overload;

{ Vec2 }
function V2(x, y: TScalar): TVec2;
function ToFloats(v: TVec2): TJSFloat32List; overload;

function RGBAb(r, g, b, a: GLubyte): TRGBAb;
function RGBAf(r, g, b, a: TScalar): TRGBAf;

implementation

{=============================================}
{@! ___Vec2___ }
{=============================================}

function V2(x, y: TScalar): TVec2;
begin
	result.x := x;
	result.y := y;
end;

function ToFloats(v: TVec2): TJSFloat32List;
begin
	SetLength(result, 2);
	result[0] := v.x;
	result[1] := v.y;
end;

{=============================================}
{@! ___Vec3___ }
{=============================================}

function V3(x, y, z: TScalar): TVec3;
begin
	result.x := x;
	result.y := y;
	result.z := z;
end;

function Add (v: TVec3; amount: TScalar): TVec3;
begin
	result := V3(v.x + amount, v.y + amount, v.z + amount);
end;

function Add (v: TVec3; amount: TVec3): TVec3;
begin
	result := V3(v.x + amount.x, v.y + amount.y, v.z + amount.z);
end;

function Subtract (v: TVec3; amount: TScalar): TVec3;
begin
	result := V3(v.x - amount, v.y - amount, v.z - amount);
end;

function Subtract (v: TVec3; amount: TVec3): TVec3;
begin
	result := V3(v.x - amount.x, v.y - amount.y, v.z - amount.z);
end;

function Multiply (v: TVec3; amount: TScalar): TVec3;
begin
	result := V3(v.x * amount, v.y * amount, v.z * amount);
end;

function Multiply (v: TVec3; amount: TVec3): TVec3;
begin
	result := V3(v.x * amount.x, v.y * amount.y, v.z * amount.z);
end;

function Divide (v: TVec3; amount: TScalar): TVec3;
begin
	result := V3(v.x / amount, v.y / amount, v.z / amount);
end;

function Divide (v: TVec3; amount: TVec3): TVec3;
begin
	result := V3(v.x / amount.x, v.y / amount.y, v.z / amount.z);
end;

function Sum (v: TVec3): TScalar;
begin
	result := v.x + v.y + v.z;
end;

function Magnitude(v: TVec3): TScalar;
begin
	result := Sqrt(Power(v.x, 2) + Power(v.y, 2) + Power(v.z, 2));
end;

function SquaredLength (v: TVec3): TScalar;
begin
	result := Sqr(v.x) + Sqr(v.y) + Sqr(v.z);
end;

function Normalize (v: TVec3): TVec3;
begin
	result := Divide(v, Magnitude(v));
end;

function Dot (v: TVec3; point: TVec3): TScalar;
begin
	result := (v.x * point.x) + (v.y * point.y) + (v.z * point.z);
end;

function Cross (v: TVec3; point: TVec3): TVec3;
begin
	result.x := (v.y * point.z) - (v.z * point.y);
	result.y := (v.z * point.x) - (v.x * point.z);
	result.z := (v.x * point.y) - (v.y * point.x);
end;

function ToFloats(v: TVec3): TJSFloat32List;
begin
	SetLength(result, 3);
	result[0] := v.x;
	result[1] := v.y;
	result[2] := v.z;
end;

function VecStr(v: TVec3): string;
begin
	result := '{'+FloatToStr(v.x)+','+FloatToStr(v.y)+','+FloatToStr(v.z)+'}';
end;

procedure Show (v: TVec3);
begin
	writeln('{',v.x,',',v.y,',',v.z,'}');
end;

{=============================================}
{@! ___Colors___ }
{=============================================}

function RGBAb(r, g, b, a: GLubyte): TRGBAb;
begin
	result[0] := r;
	result[1] := g;
	result[2] := b;
	result[3] := a;
end;

function RGBAf(r, g, b, a: GLfloat): TRGBAf;
begin
	result[0] := r;
	result[1] := g;
	result[2] := b;
	result[3] := a;
end;

end.