PasLS.Synchronization.pas

// Pascal Language Server
// Copyright 2020 Arjan Adriaanse
// Copyright 2020 Ryan Joseph

// This file is part of Pascal Language Server.

// Pascal Language Server is free software: you can redistribute it
// and/or modify it under the terms of the GNU General Public License
// as published by the Free Software Foundation, either version 3 of
// the License, or (at your option) any later version.

// Pascal Language Server is distributed in the hope that it will be
// useful, but WITHOUT ANY WARRANTY; without even the implied warranty
// of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU General Public License for more details.

// You should have received a copy of the GNU General Public License
// along with Pascal Language Server.  If not, see
// <https://www.gnu.org/licenses/>.
unit PasLS.Synchronization;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, DateUtils,
  CodeToolManager, CodeCache,
  LSP.BaseTypes, LSP.Base, LSP.Basic, PasLS.Symbols, LSP.Synchronization;

Type
  { TDidOpenTextDocument }

  TDidOpenTextDocument = class(specialize TLSPNotification<TDidOpenTextDocumentParams>)
    procedure Process(var Params : TDidOpenTextDocumentParams); override;
  end;

  { TDidSaveTextDocument }

  TDidSaveTextDocument = class(specialize TLSPNotification<TDidSaveTextDocumentParams>)
    procedure Process(var Params : TDidSaveTextDocumentParams); override;
  end;


  { TDidCloseTextDocument }

  TDidCloseTextDocument = class(specialize TLSPNotification<TDidCloseTextDocumentParams>)
    procedure Process(var Params : TDidCloseTextDocumentParams); override;
  end;
  { TDidChangeTextDocument }

  TDidChangeTextDocument = class(specialize TLSPNotification<TDidChangeTextDocumentParams>)
    procedure Process(var Params : TDidChangeTextDocumentParams); override;
  end;


implementation

uses PasLS.CheckInactiveRegions, PasLS.Diagnostics;

{ TDidChangeTextDocument }

procedure TDidChangeTextDocument.Process(var Params : TDidChangeTextDocumentParams);
var
  Code: TCodeBuffer;
  Change: TCollectionItem;
{  Range: TRange;
  StartPos, EndPos: integer;}


begin with Params do
  begin
    Code := CodeToolBoss.FindFile(textDocument.LocalPath);
    for Change in contentChanges do
      begin
        // note(ryan): can't get this working yet
        // and I'm not even sure if it's worth it
{
        Range := TTextDocumentContentChangeEvent(Change).range;
        if Range <> nil then
          begin
            //Code.LineColToPosition(Range.start.line + 1, Range.start.character + 1, StartPos);
            //Code.LineColToPosition(Range.&end.line + 1, Range.&end.character + 1, EndPos);
            DoLog('insert: %d -> %d  text=%s',[StartPos,EndPos, TTextDocumentContentChangeEvent(Change).text]);
            //Code.Replace(StartPos, EndPos - StartPos, TTextDocumentContentChangeEvent(Change).text);
          end
        else }
        Code.Source := TTextDocumentContentChangeEvent(Change).text;

        // Ryan, uncomment this to have a syntax check at
        // CheckSyntax(Self.Transport,Code);

        if SymbolManager <> nil then
          SymbolManager.FileModified(Code);
      end;
      // DoLog( 'Synched text in %d ms',[MilliSecondsBetween(Now, StartTime)]);
    end;
end;

{ TDidCloseTextDocument }

procedure TDidCloseTextDocument.Process(var Params : TDidCloseTextDocumentParams);
var
  FileName, FullPath: String;
begin
  if SymbolManager = nil then
    Exit;

  FullPath := Params.textDocument.LocalPath;
  FileName := ExtractFileName(FullPath);

  // Distinguish between workspace files and external files
  if SymbolManager.IsFileInWorkspace(FullPath) then
    SymbolManager.UnloadFile(FileName)   // Keep database symbols
  else
    SymbolManager.RemoveFile(FileName);  // Remove database symbols
end;


{ TDidSaveTextDocument }

procedure TDidSaveTextDocument.Process(var Params : TDidSaveTextDocumentParams);
var
  Code: TCodeBuffer;
  FullPath: String;
begin
  FullPath := Params.textDocument.LocalPath;
  Code := CodeToolBoss.FindFile(FullPath);

  if Code = nil then
    Exit;

  if SymbolManager <> nil then
  begin
    // Always mark as modified
    SymbolManager.FileModified(Code);

    // Proactively update database for workspace files
    if SymbolManager.IsFileInWorkspace(FullPath) then
      SymbolManager.Reload(Code, True);  // Force reload and DB update
  end;

  DiagnosticsHandler.CheckSyntax(Transport, Code);
  CheckInactiveRegions(Transport, Code, Params.textDocument.uri);
end;


{ TDidOpenTextDocument }

procedure TDidOpenTextDocument.Process(var Params : TDidOpenTextDocumentParams);
var
  Path: String;
  Code: TCodeBuffer;
begin
  with Params do
  begin
    Path := textDocument.LocalPath;
    Code := CodeToolBoss.FindFile(Path);

    // the file was not found in search paths so
    // it need to be loaded from disk
    if Code = nil then
      Code := CodeToolBoss.LoadFile(Path, False, False);
    
    //rename file will failue ,need CreateFile ,It not create file in disk.(s)
    if Code = nil then
      begin
        Code :=CodeToolBoss.CreateFile(Path);
      end;
    //allways update the source from the opened document
    Code.Source:=textDocument.text;

    DiagnosticsHandler.CheckSyntax(Transport,Code);
  
    CheckInactiveRegions(Transport, Code, textDocument.uri);

    if SymbolManager <> nil then
      SymbolManager.Reload(Code, True);
  end;
end;

end.