Declarations6: add RULE-8-7

Author: knewbury01

c/misra/src/rules/RULE-8-7/ShouldNotBeDefinedWithExternalLinkage.ql

@@ -0,0 +1,46 @@
+/**
+ * @id c/misra/should-not-be-defined-with-external-linkage
+ * @name RULE-8-7: Functions and objects should not be defined with external linkage if they are referenced in only one
+ * @description Declarations with external linkage that are referenced in only one translation unit
+ *              can indicate an intention to only have those identifiers accessible in that
+ *              translation unit and accidental future accesses in other translation units can lead
+ *              to confusing program behaviour.
+ * @kind problem
+ * @precision very-high
+ * @problem.severity error
+ * @tags external/misra/id/rule-8-7
+ *       correctness
+ *       maintainability
+ *       readability
+ *       external/misra/obligation/advisory
+ */
+
+import cpp
+import codingstandards.c.misra
+import codingstandards.cpp.Identifiers
+import codingstandards.cpp.Scope
+
+/**
+ * Re-introduce function calls into access description as
+ * "any reference"
+ */
+class Reference extends NameQualifiableElement {
+  Reference() {
+    this instanceof Access or
+    this instanceof FunctionCall
+  }
+}
+
+from ExternalIdentifiers e, Reference a1, TranslationUnit t1
+where
+  not isExcluded(e, Declarations6Package::shouldNotBeDefinedWithExternalLinkageQuery()) and
+  (a1.(Access).getTarget() = e or a1.(FunctionCall).getTarget() = e) and
+  a1.getFile() = t1 and
+  //not accessed in any other translation unit
+  not exists(TranslationUnit t2, Reference a2 |
+    not t1 = t2 and
+    (a2.(Access).getTarget() = e or a2.(FunctionCall).getTarget() = e) and
+    a2.getFile() = t2
+  )
+select e, "Declaration with external linkage is accessed in only one translation unit $@.", a1,
+  a1.toString()

c/misra/test/rules/RULE-8-7/ShouldNotBeDefinedWithExternalLinkage.expected

@@ -0,0 +1,3 @@
+| test.h:2:12:2:13 | i1 | Declaration with external linkage is accessed in only one translation unit $@. | test.c:4:5:4:6 | i1 | i1 |
+| test.h:3:5:3:6 | i2 | Declaration with external linkage is accessed in only one translation unit $@. | test.c:5:5:5:6 | i2 | i2 |
+| test.h:5:13:5:14 | f2 | Declaration with external linkage is accessed in only one translation unit $@. | test.c:7:5:7:6 | call to f2 | call to f2 |

c/misra/test/rules/RULE-8-7/ShouldNotBeDefinedWithExternalLinkage.qlref

@@ -0,0 +1 @@
+rules/RULE-8-7/ShouldNotBeDefinedWithExternalLinkage.ql

c/misra/test/rules/RULE-8-7/test.c

@@ -0,0 +1,9 @@
+#include "test.h"
+void f(){
+    i = 0;
+    i1 = 0;
+    i2 = 0;
+    f1();
+    f2();
+    f3();
+}

c/misra/test/rules/RULE-8-7/test.h

@@ -0,0 +1,7 @@
+extern int i;     // COMPLIANT - accessed multiple translation units
+extern int i1;    // NON_COMPLIANT - accessed one translation unit
+int i2;           // NON_COMPLIANT - accessed one translation unit
+extern void f1(); // COMPLIANT  - accessed multiple translation units
+extern void f2(); // NON_COMPLIANT - accessed one translation unit
+static void f3(); // COMPLIANT - internal linkage
+extern void f3(); // COMPLIANT - internal linkage

c/misra/test/rules/RULE-8-7/test1.c

@@ -0,0 +1,5 @@
+#include "test.h"
+void f(){
+    i = 0;
+    f1();
+}

cpp/common/src/codingstandards/cpp/exclusions/c/Declarations6.qll

@@ -7,7 +7,8 @@ newtype Declarations6Query =
   TFunctionDeclaredImplicitlyQuery() or
   TIdentifiersWithExternalLinkageNotUniqueQuery() or
   TIdentifiersWithInternalLinkageNotUniqueQuery() or
-  TArrayExternalLinkageSizeExplicitlySpecifiedQuery()
+  TArrayExternalLinkageSizeExplicitlySpecifiedQuery() or
+  TShouldNotBeDefinedWithExternalLinkageQuery()
 
 predicate isDeclarations6QueryMetadata(Query query, string queryId, string ruleId, string category) {
   query =
@@ -45,6 +46,15 @@ predicate isDeclarations6QueryMetadata(Query query, string queryId, string ruleI
     "c/misra/array-external-linkage-size-explicitly-specified" and
   ruleId = "RULE-8-11" and
   category = "advisory"
+  or
+  query =
+    // `Query` instance for the `shouldNotBeDefinedWithExternalLinkage` query
+    Declarations6Package::shouldNotBeDefinedWithExternalLinkageQuery() and
+  queryId =
+    // `@id` for the `shouldNotBeDefinedWithExternalLinkage` query
+    "c/misra/should-not-be-defined-with-external-linkage" and
+  ruleId = "RULE-8-7" and
+  category = "advisory"
 }
 
 module Declarations6Package {
@@ -75,4 +85,11 @@ module Declarations6Package {
       // `Query` type for `arrayExternalLinkageSizeExplicitlySpecified` query
       TQueryC(TDeclarations6PackageQuery(TArrayExternalLinkageSizeExplicitlySpecifiedQuery()))
   }
+
+  Query shouldNotBeDefinedWithExternalLinkageQuery() {
+    //autogenerate `Query` type
+    result =
+      // `Query` type for `shouldNotBeDefinedWithExternalLinkage` query
+      TQueryC(TDeclarations6PackageQuery(TShouldNotBeDefinedWithExternalLinkageQuery()))
+  }
 }

rule_packages/c/Declarations6.json

@@ -79,6 +79,27 @@
         }
       ],
       "title": "When an array with external linkage is declared, its size should be explicitly specified"
+    },
+    "RULE-8-7": {
+      "properties": {
+        "obligation": "advisory"
+      },
+      "queries": [
+        {
+          "description": "Declarations with external linkage that are referenced in only one translation unit can indicate an intention to only have those identifiers accessible in that translation unit and accidental future accesses in other translation units can lead to confusing program behaviour.",
+          "kind": "problem",
+          "name": "Functions and objects should not be defined with external linkage if they are referenced in only one",
+          "precision": "very-high",
+          "severity": "error",
+          "short_name": "ShouldNotBeDefinedWithExternalLinkage",
+          "tags": [
+            "correctness",
+            "maintainability",
+            "readability"
+          ]
+        }
+      ],
+      "title": "Functions and objects should not be defined with external linkage if they are referenced in only one translation unit"
     }
   }
 }

rules.csv

@@ -652,7 +652,7 @@ c,MISRA-C-2012,RULE-8-3,Yes,Required,,,All declarations of an object or function
 c,MISRA-C-2012,RULE-8-4,Yes,Required,,,A compatible declaration shall be visible when an object or function with external linkage is defined,,Declarations4,Medium,
 c,MISRA-C-2012,RULE-8-5,Yes,Required,,,An external object or function shall be declared once in one and only one file,,Declarations,Medium,
 c,MISRA-C-2012,RULE-8-6,Yes,Required,,,An identifier with external linkage shall have exactly one external definition,M3-2-4,Declarations4,Import,
-c,MISRA-C-2012,RULE-8-7,Yes,Advisory,,,Functions and objects should not be defined with external linkage if they are referenced in only one translation unit,,Declarations,Medium,
+c,MISRA-C-2012,RULE-8-7,Yes,Advisory,,,Functions and objects should not be defined with external linkage if they are referenced in only one translation unit,,Declarations6,Medium,
 c,MISRA-C-2012,RULE-8-8,Yes,Required,,,The static storage class specifier shall be used in all declarations of objects and functions that have internal linkage,M3-3-2,Declarations,Medium,
 c,MISRA-C-2012,RULE-8-9,Yes,Advisory,,,An object should be defined at block scope if its identifier only appears in a single function,M3-4-1,Declarations,Medium,
 c,MISRA-C-2012,RULE-8-10,Yes,Required,,,An inline function shall be declared with the static storage class,,Declarations,Medium,