Audio tools with Esp32-S2

[JosephYdr]

I am spent all day trying unsuccessfully to get audiotools working on an esp32s2 mini.
I am using an old version of the library because the new version always raises this error even on the example programs: "error: 'class libhelix::MP3DecoderHelix' has no member named 'setReference'". this old version worked on my esp32 wroom. When I run the following sketch it uploads but prints: "[E] AudioSourceSDFAT.h : 78 - sd.begin failed
[E] AudioSourceSDFAT.h : 111 - Filename is null
[W] AudioPlayer.h : 185 - -> begin: no data found
[E] AudioSourceSDFAT.h : 111 - Filename is null
[E] AudioSourceSDFAT.h : 111 - Filename is null"

#include <SPI.h>
#include <AudioTools.h>
#include <AudioLibs/AudioSourceSDFAT.h>
#include <AudioCodecs/CodecMP3Helix.h>

#define I2S_BCK_PIN  40
#define I2S_WS_PIN   39
#define I2S_DATA_PIN 38

AudioSourceSDFAT source;
I2SStream i2s;
MP3DecoderHelix decoder;
AudioPlayer player(source, i2s, decoder);

void setup() {
  Serial.begin(115200);

  // Initialize I2S for audio
  auto cfg = i2s.defaultConfig(TX_MODE);
  cfg.pin_bck  = I2S_BCK_PIN;
  cfg.pin_ws   = I2S_WS_PIN;
  cfg.pin_data = I2S_DATA_PIN;
  i2s.begin(cfg);

  player.begin();
  player.setVolume(0.5);  // 0–255
  player.setIndex(0);
  player.play();
}

void loop() {
  // Example: play a test MP3 from SD
  player.copy();  // Keep audio running
}

I have it wired as follows:

SD_CS_PIN = 34
SD_MISO_PIN = 37
SD_MOSI_PIN = 35
SD_SCK_PIN = 36

and the audio amp as defined.

[pschatzmann]

It seems that you forgot to install a new libhelix version: hence the error message about the missing function!
You sketch is missing the logic to define the SD pins: Therefore you get sd.begin failed!

Use something like the follows:

// configure SDFAT  with CS pin
SdSpiConfig sdcfg(PIN_AUDIO_KIT_SD_CARD_CS, DEDICATED_SPI, SD_SCK_MHZ(10) , &SPI);
AudioSourceSDFAT source(startFilePath, ext, sdcfg);

// Define SPI pins
SPI.begin(PIN_SD_CARD_CLK, PIN_SD_CARD_MISO, PIN_SD_CARD_MOSI, PIN_SD_CARD_CS);

ps. the comment about the volume range is wrong: it should be 0.0 - 1.0!

[JosephYdr]

Also, I do not see how this code fits with the code I previously provided. Where do the lines go?

[JosephYdr]

Of course, I should have updated libhelix too. But now it gives the error "error: invalid use of template-name 'audio_tools::AudioSourceSDFAT' without an argument list
AudioSourceSDFAT source(startFilePath, ext);
^~~~~~~~~~~~~~~~"
I am running the example sketch "player-sdfat-i2s.ino"

[pschatzmann]

Strange then you should not need to use AudioSourceSDFAT<> source; and AudioSourceSDFAT source; should work w/o any problems...

Post the actual correct code and the related output again! This is getting very confusing...

[JosephYdr]

Ok... So it suddenly started working. I have no idea why.

#include "AudioTools.h"
#include "AudioTools/Disk/AudioSourceSDFAT.h"
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"

const char *startFilePath = "/";   // folder to scan
const char *ext = "mp3";           // filter extension

// ---- SD SPI pins (ESP32-S2 Mini) ----
#define SD_CS_PIN    34
#define SD_MISO_PIN  37
#define SD_MOSI_PIN  35
#define SD_SCK_PIN   36

// ---- I2S pins ----
#define I2S_BCK_PIN  40
#define I2S_WS_PIN   39
#define I2S_DATA_PIN 38


SdSpiConfig sdcfg(SD_CS_PIN, DEDICATED_SPI, SD_SCK_MHZ(10) , &SPI);
AudioSourceSDFAT source(startFilePath, ext, sdcfg);//
I2SStream i2s;
MP3DecoderHelix decoder;
AudioPlayer player(source, i2s, decoder);

void printMetaData(MetaDataType type, const char* str, int len){
  Serial.print("==> ");
  Serial.print(toStr(type));
  Serial.print(": ");
  Serial.println(str);
}

void setup() {
  Serial.begin(115200);
  delay(1000);
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);

  SPI.begin(SD_SCK_PIN, SD_MISO_PIN, SD_MOSI_PIN, SD_CS_PIN);

  if (!source.getAudioFs().begin(SD_CS_PIN)) {
    Serial.println("[SD] init failed (getAudioFs.begin)");
    while (1) delay(100);
  }
  Serial.println("[SD] OK");
  
  source.setPath(startFilePath);


  auto cfg = i2s.defaultConfig(TX_MODE);
  cfg.pin_bck  = I2S_BCK_PIN;
  cfg.pin_ws   = I2S_WS_PIN;
  cfg.pin_data = I2S_DATA_PIN;
  i2s.begin(cfg);

  player.setMetadataCallback(printMetaData);
  player.begin();

  player.setIndex(0);
  player.setVolume(1);
  player.play();
}

void loop() {
  player.copy();
}

This code works now.
But, still nothing comes out of the amp. More tests...

[pschatzmann]

For my peace of mind: Please try to replace the ugly AudioSourceSDFAT<> with AudioSourceSDFAT!
This should work in 3.3.0

Also try to remove the redundant

  if (!source.getAudioFs().begin(SD_CS_PIN)) {
    Serial.println("[SD] init failed (getAudioFs.begin)");
    while (1) delay(100);
  }
  Serial.println("[SD] OK");

with does the above

  if (!source.begin()){
    Serial.println("[SD] init failed (getAudioFs.begin)");
    while (1) delay(100);
   }

[JosephYdr]

it seems that the reason it didn't work earlier was just a collection of missing bits. I tried each of them separately and they didn't change anything but apparently not together.
source.begin() is declared void not boolean.
I suggest updating the example.

[pschatzmann]

OK, I see: I will put this on my todo list to be changed...