DesktopManager/Icons.Manager.pas at main · tarcode-apps/DesktopManager · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
unit Icons.Manager;

interface

uses
  Winapi.Windows,
  System.SysUtils, System.Classes,
  System.Generics.Collections, System.Generics.Defaults,
  Icon.Renderers,
  Icon.Renderers.Default, Icon.Renderers.Legacy,
  Helpers.Images.Generator,
  Versions.Helpers;

type
  TIconsManager = class
  strict private
    FRenderer: IIconRenderer;

    FOptions: TIconsOptions;

    function GetRenderer: IIconRenderer;
    procedure OptionsChange(Sender: TObject);

    property Renderer: IIconRenderer read GetRenderer;
  public
    constructor Create; reintroduce;
    destructor Destroy; override;

    function GetIcon(IconParams: TIconParams; Dpi: Integer): HICON;
    function GetImage(IconParams: TIconParams; Dpi: Integer): HBITMAP;
    function GetImageAsIcon(IconParams: TIconParams; Dpi: Integer): HICON;

    property Options: TIconsOptions read FOptions;
  end;

implementation

{ TIconsManager }

constructor TIconsManager.Create;
begin
  FOptions := TIconsOptions.Create;
  with FOptions do
  begin
    IconStyle := DefaultIconStyle;
    IconTheme := DefaultIconTheme;
    OnChange := OptionsChange;
  end;
end;

destructor TIconsManager.Destroy;
begin
  FOptions.Free;
end;

function TIconsManager.GetIcon(IconParams: TIconParams; Dpi: Integer): HICON;
begin
  Result := Renderer.GenerateIcon(IconParams, Dpi);
end;

function TIconsManager.GetImage(IconParams: TIconParams; Dpi: Integer): HBITMAP;
begin
  Result := Renderer.GenerateImage(IconParams, Dpi);
end;

function TIconsManager.GetImageAsIcon(IconParams: TIconParams; Dpi: Integer): HICON;
var
  hBmp: HBITMAP;
begin
  hBmp := GetImage(IconParams, Dpi);
  Result := HBitmapToHIcon(hBmp);
  DeleteObject(hBmp);
end;

function TIconsManager.GetRenderer: IIconRenderer;
begin
  if FRenderer <> nil then Exit(FRenderer);

  case FOptions.IconStyle of
    isOld: FRenderer := TLegacyIconRenderer.Create(FOptions);
    isWin8..isWin11: FRenderer := TDefaultIconRenderer.Create(FOptions);
    else raise Exception.Create('Not supported icon style');
  end;
  Result := FRenderer;
end;

procedure TIconsManager.OptionsChange(Sender: TObject);
begin
  FRenderer := nil;
end;

end.