timer-ninja/build.gradle at master · thanglequoc/timer-ninja · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
plugins {
    id 'java-library'
    id 'application'
    id 'maven-publish'
    id 'io.freefair.aspectj' version '9.1.0'
    id 'org.jreleaser' version '1.21.0'
}

group 'io.github.thanglequoc'
version '1.3.0'

java {
    withJavadocJar()
    withSourcesJar()
    sourceCompatibility = "17"
    targetCompatibility = "17"
}

repositories {
    mavenCentral()
}

dependencies {
    implementation group: 'org.aspectj', name: 'aspectjrt', version: '1.9.25'
    implementation group: 'org.slf4j', name: 'slf4j-api', version: '[2.0.17,)'

    testImplementation 'org.junit.jupiter:junit-jupiter:6.0.1'
    testRuntimeOnly "org.junit.platform:junit-platform-launcher"

    testImplementation group: 'org.mockito', name: 'mockito-core', version: '5.20.0'
    testImplementation group: 'ch.qos.logback', name: 'logback-core', version: '1.5.21'
    testImplementation group: 'ch.qos.logback', name: 'logback-classic', version: '1.5.21'
}

test {
    useJUnitPlatform()
    jvmArgs("-XX:+EnableDynamicAgentLoading")
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = 'timer-ninja'
            from components.java

            pom {
                name = 'Timer Ninja'
                description = 'Timer Ninja is a lightweight Java library for measuring method execution time with ease. It provides annotation-based tracking and a flexible API to measure execution time, supports different time units, and visualizes the tracking context in stacktrace tree format.'
                url = 'https://github.com/ThangLeQuoc/timer-ninja'
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'thanglequoc'
                        name = 'Thang Le Quoc'
                        email = 'thanglequoc.it@gmail.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/ThangLeQuoc/timer-ninja.git'
                    developerConnection = 'scm:git:ssh://github.com/ThangLeQuoc/timer-ninja.git'
                    url = 'https://github.com/ThangLeQuoc/timer-ninja'
                }
            }
        }
    }
    repositories {
        maven {
            url = layout.buildDirectory.dir('staging-deploy')
        }
        mavenLocal()
    }
}


javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

jreleaser {
    signing {
        active = 'ALWAYS'
        armored = true
    }
    deploy {
        maven {
            mavenCentral {
                sonatype {
                    active = 'ALWAYS'
                    url = 'https://central.sonatype.com/api/v1/publisher'
                    stagingRepository('build/staging-deploy')
                }
            }
        }
    }
}