Package Updates

packages/build/package.json

@@ -1,6 +1,6 @@
 {
   "name": "@labkey/build",
-  "version": "8.8.0",
+  "version": "8.8.1-fb-package-updates-0226-deux.0",
   "description": "LabKey client-side build assets",
   "files": [
     "webpack/"
@@ -19,24 +19,24 @@
     "@babel/preset-react": "~7.28.5",
     "@babel/preset-typescript": "~7.28.5",
     "@pmmmwh/react-refresh-webpack-plugin": "~0.6.2",
-    "ajv": "~8.17.1",
+    "ajv": "~8.18.0",
     "babel-loader": "~10.0.0",
     "bootstrap-sass": "~3.4.3",
     "copy-webpack-plugin": "~13.0.1",
     "cross-env": "~10.1.0",
-    "css-loader": "~7.1.3",
+    "css-loader": "~7.1.4",
     "fork-ts-checker-webpack-plugin": "~9.1.0",
     "html-webpack-plugin": "~5.6.5",
     "mini-css-extract-plugin": "~2.10.0",
     "react-refresh": "~0.18.0",
     "resolve-url-loader": "~5.0.0",
-    "rimraf": "~6.1.2",
+    "rimraf": "~6.1.3",
     "sass": "~1.79.6",
-    "sass-loader": "~16.0.6",
+    "sass-loader": "~16.0.7",
     "source-map-loader": "~5.0.0",
     "style-loader": "~4.0.0",
     "typescript": "~5.9.3",
-    "webpack": "~5.105.0",
+    "webpack": "~5.105.2",
     "webpack-bundle-analyzer": "~5.2.0",
     "webpack-cli": "~6.0.1",
     "webpack-dev-server": "~5.2.3"

packages/components/package.json

@@ -1,6 +1,6 @@
 {
   "name": "@labkey/components",
-  "version": "7.20.4",
+  "version": "7.20.5-fb-package-updates-0226-deux.0",
   "description": "Components, models, actions, and utility functions for LabKey applications and pages",
   "sideEffects": false,
   "files": [
@@ -50,7 +50,7 @@
   "homepage": "https://github.com/LabKey/labkey-ui-components#readme",
   "dependencies": {
     "@hello-pangea/dnd": "18.0.1",
-    "@labkey/api": "1.47.0",
+    "@labkey/api": "1.47.1-fb-package-updates-0226-deux.0",
     "@testing-library/dom": "~10.4.1",
     "@testing-library/jest-dom": "~6.9.1",
     "@testing-library/react": "~16.3.2",
@@ -75,8 +75,8 @@
     "vis-network": "~10.0.2"
   },
   "devDependencies": {
-    "@labkey/build": "8.8.0",
-    "@labkey/eslint-config": "1.1.2",
+    "@labkey/build": "8.8.1-fb-package-updates-0226-deux.0",
+    "@labkey/eslint-config": "1.1.3-fb-package-updates-0226-deux.0",
     "@types/history": "4.7.11",
     "@types/jest": "30.0.0",
     "@types/node": "24.10.9",

packages/eslint-config/justfile

@@ -0,0 +1,121 @@
+# Note: this justfile should work for anyone using MacOS, however with some work we can probably get it to also work on
+# Windows if we use the [unix] and [windows] attributes on the commands that execute shell scripts:
+#   https://just.systems/man/en/attributes.html#enabling-and-disabling-recipes180
+
+[private]
+default:
+    just --list
+
+currentBranch := `git branch --show-current`
+branchAsTag := replace(currentBranch, '_', '-')
+packageName := '@labkey/eslint-config'
+
+# We trim the trailing / from our environment variables so we can treat them consistently with our other paths
+# We quote the paths from our environment variables so these variables will work even if the paths contains spaces
+labkey := quote(trim_end_match(env('LABKEY_HOME'), '/'))
+components := quote(trim_end_match(env('LABKEY_UI_COMPONENTS_HOME'), '/'))
+premium := quote(trim_end_match(env('LABKEY_UI_PREMIUM_HOME'), '/'))
+distPath := 'node_modules' / packageName / 'webpack'
+sourceDist := components / 'packages/build/webpack/'
+modules := labkey / 'server/modules'
+premiumModules := modules / 'premiumModules'
+platform := modules / 'platform'
+core := platform / 'core'
+experiment := platform / 'experiment'
+assay := platform / 'assay'
+pipeline := platform / 'pipeline'
+lims := modules / 'limsModules'
+biologics := lims / 'biologics'
+sampleManagement := lims / 'sampleManagement'
+inventory := lims / 'inventory'
+labbook := lims / 'labbook'
+puppeteer := lims / 'puppeteer'
+
+# Note: these are not all of the locations that we use @labkey/eslint-config, however they are the most common places that we
+# want to keep up to date.
+platformModules := core + ' ' + experiment + ' ' + assay + ' ' + pipeline
+appModules := premium + ' ' + biologics + ' ' + inventory + ' ' + sampleManagement
+modulesToBump := appModules + ' ' + labbook + ' ' + ' ' + puppeteer + ' ' + platformModules
+
+# Note: this is just a common subset of locations where we would want to copy a locally built package, in order to test
+# before we publish a version. You may want to add more locations (e.g. core, assay)
+copyLocations := append('/' + distPath, appModules)
+
+# Copies built package to NODE_MODULES directory for every module listed in copyLocations
+copy:
+    #!/usr/bin/env zsh
+    set -euo pipefail
+    for module in {{ copyLocations }}; do
+        echo '{{ GREEN }}'Copying built package to '{{CYAN}}'$module'{{ NORMAL }}'
+        rsync -ra {{ sourceDist }} $module
+    done
+
+# Bumps version to a prerelease version based on the current branch name
+preVersion:
+    @echo {{ GREEN }}Bumping prerelease version with preid='{{CYAN}}'{{ branchAsTag }}{{ NORMAL }}
+    npm version prerelease --preid {{ branchAsTag }} --no-git-tag-version
+
+# Publishes the current version with the current branch name as a tag
+publishPreVersion:
+    @echo {{ GREEN }}Publishing prerelease package{{ NORMAL }}
+    @npm publish --tag {{ branchAsTag }}
+
+[private]
+sleep:
+    @echo {{ GREEN }}"Sleeping so artifactory doesn't return 404"{{ NORMAL }}
+    @sleep 6
+
+# Lists the modules in the 'modulesToBump' variable
+listModules:
+    #!/usr/bin/env zsh
+    set -euo pipefail
+    for module in {{ modulesToBump }}; do
+        echo $module
+    done
+
+# Stored as a string because we want to execute this when scripts are run, not when the justfile is evaluated, so we
+# always have the most up to date version.
+
+currentVersionImport := quote("require('./package.json').version")
+
+# Bumps the @labkey/eslint-config package to the current version in every module listed in the modules variable
+_bump modules:
+    #!/usr/bin/env zsh
+    set -euo pipefail
+    v=$(node -p -e {{ currentVersionImport }})
+    echo Bumping {{ packageName }} to '{{CYAN}}'$v
+    for module in {{ modules }}; do
+        pushd $module
+        echo '{{ GREEN }}'Bumping {{ packageName }} in '{{CYAN}}'$(pwd)'{{ NORMAL }}'
+        npm install --legacy-peer-deps --save-exact {{ packageName }}@$v
+        popd
+    done
+
+# Bumps the @labkey/eslint-config package to the current version in every module listed in the 'modulesToBump' variable
+bump: (_bump modulesToBump)
+
+# Bumps the @labkey/eslint-config package to the current version in every module listed in the 'appModules' variable
+bumpApps: (_bump appModules)
+
+# Bumps the version to a prerelease version based on the current branch name, publishes the version, and bumps it in every module listed in 'modulesToBump'
+release: preVersion publishPreVersion sleep bump
+
+# Bumps the version to a prerelease version based on the current branch name, publishes the version, and bumps it in every module listed in 'appModules'
+releaseApps: preVersion publishPreVersion sleep bumpApps
+
+# Bumps the major version
+major:
+    @npm version major --no-git-tag-version
+
+# Bumps the minor version
+minor:
+    @npm version major --no-git-tag-version
+
+# Bumps the patch version
+patch:
+    @npm version patch --no-git-tag-version
+
+# Publishes the current version, must be a production version
+publish:
+    @echo {{ GREEN }}Publishing release version{{ NORMAL }}
+    @npm publish